Thursday, March 10, 2011

When is a Blog not a Blog?

I most often just post whatever is on my mind at the time, but I also keep a few links to past post on the side. These posts are things I update from time to time and generally try and keep up to date. Things like links to the add-ons I use or copies of macros I made. Stuff that is as much a resource for me as it is for anyone else if not more so.

So in case your wondering where a post about rogue macros came from it's just reference information which I will link to from my macros post and update as time goes on. I actually have a ton of macro updates to get up as I haven't updated them since forever. I also have some mage macros to put up which I was just one click away from posting before my browser died. Oh well I'll get to it another time.

As for some druidy content, here's one on my newest druid macros which combines stampeding roar and dash into once easy to use button.

#showtooltip [form:1] Stampeding Roar; [mod,nogroup][mod,nocombat][nomod,group,combat] Stampeding Roar(Cat Form); Dash
/use [form:1]Stampeding Roar; [noform:3] Cat Form; [mod,nogroup][mod,nocombat][nomod,group,combat] Stampeding Roar(Cat Form); Dash

It's a beast! Nearing the 255 character cap for something pretty simple. I blame the obnoxiously long spell names. If I couldn't omit (Bear Form) from stampeding roar in bear form it couldn't possibly fit.

Basically if you are in combat and in a group it will use savage roar, otherwise it will use dash. It will use the opposite when a modifier key is used. Savage roar is always used in bear form as there is no other choice (unless you are an engineer or worgen, I am neither). If you aren't in a form you will be placed in cat form so hitting the button twice from caster form will put you in cat and then make you go fast. So its handy for ferals and casters.

I actually spent a fair bit of time squishing all my druid macros into just the space allotted for my druid. Good times. I should have that information available either tomorrow or early next week.

Rogue Macros

Eviscerate/Stealth

To save space on my action bars and because I was already used to combining prowl and ferocious bite on my druid this macro came rather naturally.

#showtooltip
/use [combat] Eviscerate; Stealth

Trick of the Trade

Every rogue loves to redirect some threat off themselves whenever they can. This macro will set a focus target when right clicked and when used with a key-bind or left click will cast Tricks of the Trade on your focus target. If a focus target does not exist it will cast tricks on whichever party member you have selected. If you are targeting a hostile then it will cast tricks on whomever that hostile is targeting (sucks for them if it isn't a tank). Finally if none of those targets were valid you will get a hand cursor to click on a target manually (right click to cancel without choosing a target).

#showtooltip
/focus [btn:2][raid,@focus,noexists]
/stopmacro [btn:2]
/use [@focus,help,nodead,raid][help,nodead,raid][harm,@targettarget,help,nodead,raid][] Tricks of the Trade

Cloak of Shadows/Shiv

I use the same button for cleansing and removing enrage effects on all my toons which share the same hot key of course. So for classes that can do both (just my rogue and druid I believe) I just base which I do on what I have targeted. If I have a hostile targeted I will shiv it and hopefully remove an enrage effect and if I have don't or am holding down a modifier I will cast cloak of shadows on myself.

#showtooltip
/use [nomod,harm] Shiv; [@player] Cloak of Shadows;

Applying Poisons

Use without modifier to apply instant poison to your main hand or with modifier to apply deadly poison to your offhand. Right click to apply instant poison to your thrown weapon. Last line automatically accepts replacing an existing poison on your weapon when the pop-up would normally appear.

#showtooltip
/use [mod] Deadly Poison; Instant Poison
/use [btn:2] 18; [mod] 17; 16
/click StaticPopup1Button1

The next three are all pretty much the same. Click to apply the specified poison to your offhand or right click to apply it to your thrown weapon.

#showtooltip
/use Crippling Poison
/use [btn:2] 18; 17
/click StaticPopup1Button1
#showtooltip
/use Mind-numbing Poison
/use [btn:2] 18; 17
/click StaticPopup1Button1

#showtooltip
/use Wound Poison
/use [btn:2] 18; 17
/click StaticPopup1Button1